▷ Comunicación Serial Bidireccional con Arduino y Bluetooth usando JSON

Aprende a implementar comunicación serial bidireccional entre Arduino y una aplicación móvil creada en App Inventor, utilizando Bluetooth y JSON para transmitir información de forma organizada y estructurada. Control de LEDs, lectura de pulsadores y ajuste de brillo mediante PWM.

Características del Proyecto

Materiales Necesarios

Diagrama de conexiones

Librerías Utilizadas

#include <SoftwareSerial.h>
#define rxPin 10
#define txPin 11
SoftwareSerial mySerial(rxPin, txPin);

#include <ArduinoJson.h>

JsonDocument doc;
deserializeJson(doc, str);
serializeJson(doc, mySerial);

Estructura del JSON

{"Switch1":true,"Switch2":false,"slider1":128}

{"Switch1":"true","Switch2":"false"}

Flujo de Comunicación

Explicación del Código

Control de LEDs y Pulsadores

int leds[2] = { 13, 3 }; // Pines de LEDs
int ledControlBrillo = 6; // Pin PWM para brillo
int pulsadores[2] = { 2, 4 }; // Pines de pulsadores

for (int i = 0; i < numeroDeDatos; i++) {
  digitalWrite(leds[i], dato[i]);
}

analogWrite(ledControlBrillo, valorSlider);

if (estadoPulsador[i] != estadoPrevio[i] && estadoPulsador[i] == HIGH) {
  dato[i] = !dato[i]; // Toggle
  delay(10); // Pausa
}
estadoPrevio[i] = estadoPulsador[i];

Código Completo

#include <ArduinoJson.h>
#include <SoftwareSerial.h>
#define rxPin 10
#define txPin 11

SoftwareSerial mySerial(rxPin, txPin);

int leds[2] = { 13, 3 };
int ledControlBrillo = 6;

int pulsadores[2] = { 2, 4 };

String str = "";

const int numeroDeDatos = 2;
int dato[numeroDeDatos];
int valorSlider = 0;

bool estadoPrevio[2] = { 0, 0 };

void setup() {
  mySerial.begin(9600);
  Serial.begin(9600);
  for (int i = 0; i < numeroDeDatos; i++) {
    pinMode(leds[i], OUTPUT);
    digitalWrite(leds[i], LOW);
    pinMode(pulsadores[i], INPUT_PULLUP);
  }
  pinMode(ledControlBrillo, OUTPUT);
}

void loop() {

  JsonDocument doc;

  if (mySerial.available() > 0) {

    str = mySerial.readStringUntil('}');

    str.concat("}");

    Serial.println(str);
    DeserializationError error = deserializeJson(doc, str);

    if (error) {
      Serial.print(F("deserializeJson() failed: "));
      Serial.println(error.f_str());
      return;
    }

    dato[0] = doc["Switch1"].as<boolean>();
    dato[1] = doc["Switch2"].as<boolean>();
    valorSlider = doc["slider1"].as<int>();
  }

  bool estadoPulsador[2] = { 0, 0 };

  for (int i = 0; i < numeroDeDatos; i++) {
    estadoPulsador[i] = digitalRead(pulsadores[i]);

    if (estadoPulsador[i] != estadoPrevio[i] && estadoPulsador[i] == HIGH) {

      dato[i] = !dato[i];
      doc["Switch1"] = dato[0] ? "true" : "false";
      doc["Switch2"] = dato[1] ? "true" : "false";

      serializeJson(doc, mySerial);
    }
    delay(10);
    estadoPrevio[i] = estadoPulsador[i];

    digitalWrite(leds[i], dato[i]);
  }

  analogWrite(ledControlBrillo, valorSlider);
}
  

Repositorio GitHub

Esquema de Conexión